*********************************************************************
* Kontakt in Outlook anlegen
* Alle Felder sind durch Konstanten ersetzt, das Programm sollte ohne Änderung funktionieren
*********************************************************************
LPARAMETER lcmenütext
LOCAL loApp, loNamespace, loKontakt, lcsuchwert, lcangbenutzer, lcbenutzer, lcörtlichkeit, benutzerordner

WAIT WINDOW "Outlook wird gestartet..." NOWAIT NOCLEAR
loApp 			= CREATEOBJECT( "Outlook.Application" )		&& Oultook Instanz laden
loNamespace 	= loApp.GetNamespace( "Mapi" )					&& Referenz auf NAMESPACE Objekt MAPI holen und anloggen
loNamespace.logon()
*********************************************************************
lcbenutzer 		= ALLTRIM("Frank Schippan")						&& PostfachName, wenn leer dann wird lokales PF benutzt
lcbenutzer 		= space(0)												&& PostfachName, wenn leer dann wird lokales PF benutzt
lcangbenutzer	= loNamespace.CreateRecipient(lcbenutzer)
lcangbenutzer.Resolve													&& existiert das Postfach ?

IF lcangbenutzer.Resolved
    benutzerordner = loNamespace.GetSharedDefaultFolder(lcangbenutzer, "10")
ELSE
	IF !EMPTY(lcBenutzer)
		messagebox(	"Es wird keine Adresse angelegt, da das angegebene" 			 + CHR(13) + ;
					"Postfach für Microsoft Outlook ungültig ist."	+ CHR(13) + CHR(13) + ;
					"Bitte informieren Sie Ihren Systemadministrator.",48,"Warnung")
		WAIT CLEAR
		RETURN
	ENDIF
	benutzerordner = loNamespace.GetDefaultFolder("10")
ENDIF
*********************************************************************
lcsuchwert = '[FileAS] = "' + "Schippan Harro" +'"'
loKontakt = benutzerordner.items.FIND(lcsuchwert)		&& Suche den Kontakt

IF TYPE('loKontakt') = 'O' AND !ISNULL(loKontakt)
	WAIT WINDOW "Adresse wird in Outlook aktualisiert..." NOWAIT NOCLEAR
ELSE
	WAIT WINDOW "Adresse wird in Outlook angelegt..." 		NOWAIT NOCLEAR
	loKontakt = benutzerordner.items.ADD(2)				&& Kontakt wird angelegt
ENDIF

WITH loKontakt
	.Body								= "bla bla bla" + CHR(13)+CHR(10)							&& großes Notizfeld unten
	.TITLE							= "Herr"																&& Anrede und Titel
	.FirstName						= "Harro"															&& Vorname
	.LastName						= "Schippan"														&& Nachname
	.INITIALS						= "H" + "." + "S" + "."											&& Initialien
	.Gender							= IIF("Herr" = "Frau", 1, IIF("Herr" = "Herr", 2, 0))	&& Geschlecht
	.CompanyName					= "Datenchnik Schippan GmbH"									&& Firmenname
	.CustomerID						= "4711"																&& Adressnummer
	.Email1Address					= "Schippan@T-Online.de"										&& Emailadresse
	.MobileTelephoneNumber		= "0171 / 976 64 16"												&& Mobilfunktelefonnummer
	.BusinessAddressCity			= "Düsseldorf"														&& Ort geschäftlich
	.BusinessAddressPostalCode	= "40625"															&& Postleitzahl geschäftlich
	.BusinessAddressStreet		= "Meißener Straße 4"											&& Straße geschäftlich
	.BusinessFaxNumber			= "0211 / 98 91 629"												&& Fax geschäftlich
	.BusinessTelephoneNumber	= "0211 / 98 91 627"												&& Telefon geschäftlich
	.JobTitle						= "Big Boss"														&& Position
	.Department						= "xx"																&& Abteilung
	.FileAs							= "Schippan" + ', ' + "Harro"									&& Speichern unter
	.Birthday						= ctod("01.01.1900")
	lcmenütext = "nix"
	IF lcmenütext = "Speichern"
		.SAVE()		&& speichern ohne Anzeige
	ELSE
		.DISPLAY()	&& Kontakt kreieren aber noch nicht speichern
	ENDIF
ENDWITH

benutzerordner	= .NULL.
loKontakt		= .NULL.
loNamespace 	= .NULL.
loApp				= .NULL.
WAIT CLEAR